Geek asks and answers

Hash Merge / Concatenation

this is the dump of my hashes:% hash1

$VAR1 = {
    abc => {
        123 => [
          'xx',
          'yy',
          'zy'
        ],
        456 => [
          'ab',
          'cd',
          'ef'
        ]
    }
};

and second:% hash2

$VAR2 = { 
    def => {
        659 => [
            'wx',
            'yg',
            'kl'
        ],
        456 => [
            'as',
            'sd',
            'df'
        ]
    },
    abc => {
        987 => [
            'lk',
            'dm',
            'sd'
        ]
    }
};

Now I want to combine these two hashes into a new hash, but if you duplicate the key (here "abc"), the values ​​should be added, not replaced, so the keys must remain unique and all values ​​must also be saved. How can this be done in Perl? The output should be as follows:

$VAR1 = {
    def => {
        659 => [
            'wx',
            'yg',
            'kl'
        ],
        456 => [
            'as',
            'sd',
            'df'
        ]
    },
    abc => {
        987 => [
            'lk',
            'dm',
            'sd'
        ],
        123 => [
            'xx',
            'yy',
            'zy'
        ],
        456 => [
            'ab',
            'cd',
            'ef'
        ]
    }
 };
+5
source share
4 answers
for my $x (keys(%h2)) {
    for my $y (keys(%{ $h2{$x} })) {
        push @{ $h1{$x}{$y} }, @{ $h2{$x}{$y} };
    }
}
+4
source

Use CPAN Hash::Mergeor modules Hash::Merge::Simple. The first one is very customizable, and the second one is very easy to use.

+7
source 
sub merge_hashes {
    my ($h1, $h2) = @_;
    foreach my $key (keys %$h2) {
        if (!exists $h1->{$key} || ref($h1->{$key}) ne 'HASH' || ref($h2->{$key}) ne 'HASH') {

            $h1->{$key} = $h2->{$key};
        }
        else {
            merge_hashes($h1->{$key}, $h2->{$key});
        }
    }
}

merge_hashes(\%hash1, \%hash2);
0
source

For the provided example data, the following merge description that you describe:

my %merged = map {
               $_ => {
                       %{$a{$_} // {}},
                       %{$b{$_} // {}}
                     }
             } ( keys %a, keys %b );

Test:

use strict;
use warnings;
use Data::Dump 'dd';

my %a = (
abc => {
        123 => [
          'xx',
          'yy',
          'zy'
        ],
        456 => [
          'ab',
          'cd',
          'ef'
        ]
    }
);
my %b = (
def => {
        659 => [
            'wx',
            'yg',
            'kl'
        ],
        456 => [
            'as',
            'sd',
            'df'
        ]
    },
    abc => {
        987 => [
            'lk',
            'dm',
            'sd'
        ]
    }
);

my %merged = map {
                   $_ => {
                           %{$a{$_} // {}},
                           %{$b{$_} // {}}
                         }
                 } ( keys %a, keys %b );

dd \%merged;
# {
#   abc => {
#            123 => ["xx", "yy", "zy"],
#            456 => ["ab", "cd", "ef"],
#            987 => ["lk", "dm", "sd"],
#          },
#   def => { 456 => ["as", "sd", "df"], 659 => ["wx", "yg", "kl"] },
# }
0
source

More articles:


All Articles